黑马程序员技术交流社区

标题: 【分享】ahk键盘映射脚本 [打印本页]

---

作者: jmw    时间: 2015-8-19 21:18
标题: 【分享】ahk键盘映射脚本
该脚本映射了一些按键，操作起来非常方便

#SingleInstance force  ;该行作用为如果程序自身被重复运行则自动Reload
#InstallKeybdHook  ;强制安装键盘钩子
#InstallMouseHook  ;强制安装鼠标钩子
Suspend, ON  ;程序启动后默认关闭FN，若需要默认打开Fn则将ON改为OFF
SetScrollLockState, AlwaysOff  ;ScrollLock LED 熄灭 (配合Suspend On的Fn关闭状态）
SoundBeep 500, 200  ;以500HZ频率，鸣响200mS时间

CapsLock::
Suspend, Permit  ;使本热键调用永远有效，避免该子程序因热键挂起（Suspend ON）而不能被热键调用
Suspend, OFF
SetScrollLockState, AlwaysOn
;SoundBeep 1000, 100  ;按下（打开）Fn-Level后的声音提示
KeyWait, CapsLock
Suspend, ON
SetScrollLockState, AlwaysOff
;SoundBeep 500,200  ;释放（关闭）Fn-Level后的声音提示
;ToolTip, %A_ThisHotkey% . "-" . %A_PriorHotkey% . "-" . %A_PriorKey%
If ("CapsLock" == A_PriorKey){
    State := GetKeyState("CapsLock", "T")
    SetCapsLockState, % State ? "Off" : "On"
}
return

LShift & RShift::
RShift & LShift::
Suspend, Permit
Suspend, Toggle
If (A_IsSuspended = 0) {
    SetScrollLockState, AlwaysOn
    SoundBeep 1000,100  ;打开Fn-Toggle后的声音提示
}
Else{
    SetScrollLockState, AlwaysOff                
    SoundBeep 500,200  ;关闭Fn-Toggle后的声音提示
}
return

i::Up
j::Left
k::Down
l::Right
`;::BackSpace
'::Del
u::Home
o::End
f::LShift
d::LControl
n::z
<+Enter::Send, {End}{Enter}

---

欢迎光临 黑马程序员技术交流社区 (http://bbs.itheima.com/)

黑马程序员IT技术论坛 X3.2