【原创】cmd界面下一键编译、执行java代码的bat脚本 - 黑马程序员技术交流社区

@echo off
if not exist %SystemRoot%\system32\choice.exe echo 抱歉，系统缺少程序运行必须组件，无法继续&pause>nul&exit /b 1
if not exist %SystemRoot%\jc.bat copy %0 %SystemRoot%\jc.bat 1>nul 2>nul & echo 配置成功，使用方法 jc &pause>nul&exit /b 0
rem 制作时间2015年10月23日 xin3283@qq.com
rem 用途：将当前目录下的java文件编译并执行
set jclog=%temp%\javac.log
if exist %jclog% 1 0>%jclog% 2>nul
javac *.java 2>%jclog%
(for /f "skip=6 tokens=2 delims=个文件 " %%i in ('dir /-c %jclog%') do @echo %%i|findstr /v "目录") >%temp%\jcSize.txt
set /p size=<%temp%\jcSize.txt
if not "%size%"=="0" (
type %jclog%
exit /b 1
)
setlocal enabledelayedexpansion
set /a MainSum=1
for %%a in (*.java) do (
type %%a|findstr /i "main" && ( set main!MainSum!=%%a & set /a MainSum=MainSum+1)
)>nul
set /a MainSum=MainSum-1
for /l %%a in (1,1,%MainSum%) do (
set main%%a=!main%%a:~0,-6!
)
if "%MainSum%"=="0" (
echo 错误: 找不到或无法加载主类,请检查Main函数
exit /b 2
) else if "%MainSum%"=="1" (
java %main1%
exit /b 0
)
echo 存在以下主函数，选择
for /l %%i in (1,1,%MainSum%) do echo %%i:!main%%i!.java
choice /c 123456789 /n
java !main%errorlevel%!
exit /b 0

复制代码